Dúvida com fórmula Vlookup para valor específico.

[Bmcs]

Boa Tarde

Após várias pesquisas continuo sem conseguir encontrar uma solução para a minha dúvida.

Com base no que apresento abaixo..

Necessito de passar só os valores (CODIGO e DESCRIÇÃO) que contenham o ID "24" para a tabela de baixo.

O ideal seria com um Vlookup, uma vez que isto é apenas um exemplo, e na realidade o que preciso é de passar valores de uma tabela para a outra com base nos IDs que estão á sua frente.

 

[lnarciso]

Boas,

Usando o PROCV resolves parte do problema.
Tens que colocar a primeira fórmula no código e a segunda na descrição:
=SE.ERRO(PROCV(A13;$A$2:$C$9;2;FALSO);"")
=SE.ERRO(PROCV(A13;$A$2:$C$9;3;FALSO);"")

passa as colunas do ID para a esquerda senão o comando não procura como deve ser os valores.

Mas depois tens o problema de haver mais que um resultado com o mesmo ID mas já te resolvo isso dá-me mais um tempo que estou com outras coisas em mãos.

 

[lnarciso]

melhor usa antes a fórmula:
=SE.ERRO(ÍNDICE($A$2:$C$9;CORRESP(C13;$C$2:$C$9;0);1);"")
(para procurares os códigos)
=SE.ERRO(ÍNDICE($A$2:$C$9;CORRESP(C13;$C$2:$C$9;0);2);"")
(para procurares as descrições)

assim escusas de ter que passar a coluna dos IDs para a esquerda

Já te digo o resto da fórmula

 

[lnarciso]

Agora a fórmula corrigida a fazer o que julgo ser o que pretendes:

Para conseguires os dados de todos os IDs com 24, tens que fazer uma fórmula matricial, ou seja em vez de carregares enter ao terminar a fórumla, pressiona ctrl+shift+enter para a fórmula ficar "matricial" (a diferença é que as fórmulas abaixo iram ficar entre parênteses {})

No código coloca:
=SE.ERRO(ÍNDICE($A$2:$C$9;MENOR(SE($C$2:$C$9=C13;LIN($A$2:$C$9)-LIN($C$1));LIN(1:1));1);"")

e na descrição:
=SE.ERRO(ÍNDICE($A$2:$C$9;MENOR(SE($C$2:$C$9=C13;LIN($A$2:$C$9)-LIN($C$1));LIN(1:1));2);"")

repete esta fórmula em várias colunas e quando deixar de aparecer valores significa que não encontrou mais valores com o ID 24.

alguma dúvida pergunta.